• Home
 · 
• Windows System Services
 · 
• WMI sample: retrieves printer status on local or remote computer. Written in VBScript. Uses win32_P

WMI sample: retrieves printer status on local or remote computer. Written in VBScript. Uses win32_P

WMI sample: retrieves printer status on local or remote computer. Written in VBScript. Uses win32_Printer WMI class.

Rate WMI sample: retrieves printer status on local or remote computer. Written in VBScript. Uses win32_P

• 1
• 2
• 3
• 4
• 5

(3(3 Vote))

' This function checks if a printer is up-and-running
' Requires WMI

' Check out http://www.activexperts.com for more samples and components


Const PrinterIdle = 3
Const PrinterPrinting = 4
Const PrinterWarmingUp = 5

Function IsPrinterUp( strPrintServer, strPrinter )
    Dim strobject, PrinterSet, Printer

    IsPrinterUp = False

    strObject = "winmgmts://" & strPrintServer
    Set PrinterSet = GetObject( strObject ).InstancesOf( "win32_Printer" )
    If( PrinterSet.Count = 0 ) Then 
        Exit Function
    End If

    For Each Printer in PrinterSet 
        WScript.Echo Printer.Name & " ==> " & Printer.PrinterStatus 
        If UCase( Printer.name ) = UCase( strPrinter  ) Then
	       If Printer.PrinterStatus = PrinterIdle Or Printer.PrinterStatus = PrinterPrinting Or Printer.PrinterStatus = PrinterWarmingUp Then
                IsPrinterUp = True
                Exit Function
           End If 
        End If           
    Next
	
End Function



' Main

Dim strPrintServer, strPrinterName
Do
   strPrinterName = inputbox( "Please enter the name of the printer", "Input" )
Loop until strPrinterName <> ""
Do
   strPrintServer = inputbox( "Please enter the name of the printserver", "Input" )
Loop until strPrintServer <> ""
If( IsPrinterUp( strPrintServer, strPrinterName ) = True ) Then
    WScript.Echo "Printer " & strPrinterName & " is OK"
Else
    WScript.Echo "Printer " & strPrinterName & " is NOT OK"
End If