• Home
 · 
• Files/File Controls/Input/Output
 · 
• RmDir

RmDir

This Procedure Deletes all Files in Directory as well as all Sub Directories and Files

Inputs
vFile = Directory to Delete

API Declarations



Rate RmDir

• 1
• 2
• 3
• 4
• 5

(3(3 Vote))

'###########################################
'# Removes an Entire Directory Structure #
'# ------------------------------------- #
'# Created By : Robert A. Charest Jr.   #
'# E-mail   : [email protected] #
'###########################################
Public Sub RmTree(ByVal vDir As Variant)
  
  Dim vFile As Variant
  
  ' Check if "\" was placed at end
  ' If So, Remove it
  If Right(vDir, 1) = "\" Then
    vDir = Left(vDir, Len(vDir) - 1)
  End If
  
  ' Check if Directory is Valid
  ' If Not, Exit Sub
  vFile = Dir(vDir, vbDirectory)
  If vFile = "" Then
    Exit Sub
  End If
  
  ' Search For First File
  vFile = Dir(vDir & "\", vbDirectory)
  
  ' Loop Until All Files and Directories
  ' Have been Deleted
  Do Until vFile = ""
    
    If vFile = "." Or vFile = ".." Then
      vFile = Dir
    
    ElseIf (GetAttr(vDir & "\" & vFile) And _
      vbDirectory) = vbDirectory Then
      RmTree vDir & "\" & vFile
      vFile = Dir(vDir & "\", vbDirectory)
    
    Else
      Kill vDir & "\" & vFile
      vFile = Dir
    
    End If
    
  Loop
  
  ' Remove Top Most Directory
  RmDir vDir
  
End Sub