VBcoders Guest



Don't have an account yet? Register
 


Forgot Password?



A dead good example of Automation with Outlook

by John Edward Colman (7 Submissions)
Category: OLE/COM/DCOM/Active-X
Compatability: Visual Basic 3.0
Difficulty: Intermediate
Date Added: Wed 3rd February 2021
Rating: (16 Votes)

This demonstration program gives examples of how you can control Outlook using AUTOMATION to create mail, contacts and appointments.
You can adapt this code to create the other outlook items.

Assumes
I supplied the sub-routines but you'll need to create text boxes and command buttons to call them.
Code Returns
Creates Outlook objects
Side Effects
You'll still need to supply Outlook login info.
API Declarations
Perform the following menu operations:
Project > References
Put a check next to:
"Microsoft Outlook 8.0 Object Library" or equivalent

Rate A dead good example of Automation with Outlook

Option Explicit
'Create an object to refererence the Outlook App.
'This is simular to a pointer and is declared in this way...
'...to allow early binding, making the code more efficient.
Private o1 As Outlook.Application
Private Sub Form_Load()
  
  'Create an instance of Outlook
  Set o1 = New Outlook.Application
End Sub
Private Sub Form_Terminate()
  
  'Comment out this line if you don't want to close Outlook
  o1.Quit
  
  'The next line frees up the memory used
  Set o1 = Nothing
  
End Sub

Private Sub CreateEmail(Recipient As String, Subject As String, Body As String, Attach As String)
  
  'Create a reference to a mail item
  Dim e1 As Outlook.MailItem
  
  'Create a new mail item
  Set e1 = o1.CreateItem(olMailItem)
  
  'Set a few of the many possible message parameters.
  e1.To = Recipient
  e1.Subject = Subject
  e1.Body = Body
  
  'This is how you add attatchments
  If Attach <> vbNullString Then
    e1.Attachments.Add Path
  End If
  
  'Commit the message
  e1.Send
  'Free up the space
  Set e1 = Nothing
  
End Sub

Private Sub CreateContact(Name As String, Nick As String, Email As String)
  
  'Create a reference to a Contact item
  Dim e1 As Outlook.ContactItem
  
  'Create a new contact item
  Set e1 = o1.CreateItem(olContactItem)
  
  'Set a few of the many possible contact parameters.
  e1.FullName = Name
  e1.NickName = Nick
  e1.Email1Address = Email
  
  'Commit the contact
  e1.Save
  'Free up the space
  Set e1 = Nothing
  
End Sub
Private Sub CreateAppointment(StartTime As Date, Endtime As Date, Subject As String, Location As String)
  
  'Create a reference to a Appointment item
  Dim e1 As Outlook.AppointmentItem
  
  'Create a new appointment item
  Set e1 = o1.CreateItem(olAppointmentItem)
  
  'Set a few of the many possible appointment parameters.
  e1.Start = StartTime
  e1.End = Endtime
  e1.Subject = Subject
  e1.Location = Location
  
  'If you want to set a list of recipients, do it like this
  'e1.Recipients.Add Name
  
  'Commit the appointment
  e1.Send
  'Free up the space
  Set e1 = Nothing
  
End Sub

Download this snippet    Add to My Saved Code

A dead good example of Automation with Outlook Comments

No comments have been posted about A dead good example of Automation with Outlook. Why not be the first to post a comment about A dead good example of Automation with Outlook.

Post your comment

Subject:
Message:
0/1000 characters